递归火山软件开发平台

标题: dll初始化成功,无法正确获取结构体成员,求大佬指点 [打印本页]

作者: kanshijian 时间: 3 天前
标题: dll初始化成功,无法正确获取结构体成员,求大佬指点
<火山程序类型 = "通常" 版本 = 1 />

方法按钮_被单击 <接收事件类型 = 整数注释 = "当按钮被单击后发送此事件">
参数来源对象 <类型 = 按钮注释 = "提供事件产生的具体来源对象">
参数标记值 <类型 = 整数注释 = "用户调用\"挂接事件\"命令时所提供的\"标记值\"参数值,非此方式挂接事件则本参数值固定为0.">
{
如果 (来源对象 == 按钮1)
{
      变量详细表 <类型 = 流量统计类>
      变量 mib表 <类型 = MIB_IF_TABLE2>
      变量表地址 <类型 = 变整数>
      变量获取数组 <类型 = 结构体数组类>

      调试输出 (流量统计类.获取网卡接口信息 (mib表))

      调试输出 (mib表.NumEntries)
      调试输出 (mib表.Table.为指定对象类 (MIB_IF_ROW2))
      调试输出 (mib表.Table.取成员数 ())

}
返回 (0)
}

类流量统计类 <公开>
{
方法获取网卡接口信息 <公开静态类型 = 变整数注释 = "常见返回值：" 注释 = "NO_ERROR (0)：函数调用成功。Table 参数现在指向包含接口信息的有效数据。"
         注释 = "ERROR_NOT_ENOUGH_MEMORY (8)：内存不足，无法分配存储表的缓冲区。"
         注释 = "ERROR_NOT_SUPPORTED (50)：当前操作系统不支持此函数（GetIfTable2 需要 Windows Vista 或更高版本）。"
         注释 = "ERROR_INVALID_PARAMETER (87)：参数无效（例如传入了空指针）。"
         注释 = "ERROR_NOT_FOUND (1168)：未找到元素（通常不太可能，因为至少会有一个回环接口）。" @输出名 = "GetIfTable2"
         @视窗.输入 = "Iphlpapi.dll">
参数 table <类型 = MIB_IF_TABLE2 @视窗.输出参数 = 真>
{

}
}

类结构体数组类 <公开基础类 = 对象数组模板类 @模板实现类 = "MIB_IF_ROW2">
{

#
}

类 MIB_IF_ROW2 <公开基础类 = 结构体数组类 @视窗.结构类 = 0>
{
变量 InterfaceIndex <类型 = 变整数>
变量 Description <类型 = 变整数>
变量 InOctets <类型 = 长整数>
变量 OutOctets <类型 = 长整数>

#
}

#
#

类 MIB_IF_TABLE2 <公开 @视窗.结构类 = 0>
{
变量 NumEntries <公开类型 = 变整数注释 = "接口数量">
变量 Table <公开类型 = MIB_IF_ROW2 注释 = "接口数组指针" "">

#
#
#
#
}

作者: Xelloss0618 时间: 3 天前
<火山程序类型 = "通常" 版本 = 1 />

类流量统计类 <公开折叠 @视窗.预定义宏 = "_WIN32_WINNT=0x600" @视窗.外部头文件 = "Iphlpapi.h" @视窗.外部库 = "Iphlpapi.lib">
{
方法获取网卡接口信息 <公开静态类型 = 整数折叠 @嵌入式方法 = "">
参数 table <类型 = MIB_IF_TABLE2指针>
{
      @ GetIfTable2(&@<table>)
}
}

类 MIB_IF_ROW2 <公开注释 = "成员太多了,只封一部分"
      注释 = "https://learn.microsoft.com/zh-cn/windows/win32/api/netioapi/ns-netioapi-mib_if_row2" 折叠
      @别名 = "MIB_IF_ROW2" @别名类型 = 本地结构>
{
变量 InterfaceIndex <公开类型 = 整数 @输出名 = "InterfaceIndex">
变量 Description <公开类型 = 文本指针 @输出名 = "Description">
变量 InOctets <公开类型 = 长整数 @输出名 = "InOctets">
变量 OutOctets <公开类型 = 长整数 @输出名 = "OutOctets">
}

类 MIB_IF_TABLE2指针 <公开折叠 @别名 = "PMIB_IF_TABLE2" @别名类型 = 本地参考类型>
{
变量成员数 <公开类型 = 整数注释 = "接口数量" @输出名 = "NumEntries">

方法销毁 <公开静态注释 = "不再使用时必须调用此方法释放内存" 折叠 @嵌入式方法 = "">
参数本结构指针 <类型 = MIB_IF_TABLE2指针>
{
      @ FreeMibTable(@<本结构指针>)
}

方法取成员 <公开静态类型 = MIB_IF_ROW2 折叠 @嵌入式方法 = "">
参数本结构指针 <类型 = MIB_IF_TABLE2指针>
参数索引 <@匹配类型 = 通用整数型>
{
      @ @<本结构指针>->Table[@<索引>]
}

方法枚举循环 <公开静态折叠 @嵌入式方法 = "name = mib_counter\r\nhas_loop_body = true">
参数本结构指针 <类型 = MIB_IF_TABLE2指针>
{
      @ for (ULONG __mib_if_table2_itr = 0; __mib_if_table2_itr < @<本结构指针>->NumEntries; __mib_if_table2_itr++)
}

方法取枚举值 <公开静态类型 = MIB_IF_ROW2 折叠 @嵌入式方法 = "parent = mib_counter">
参数本结构指针 <类型 = MIB_IF_TABLE2指针>
{
      @ @<本结构指针>->Table[__mib_if_table2_itr]
}
}

类例程 <折叠>
{
方法例子 <公开静态>
{
      变量 MIB <类型 = MIB_IF_TABLE2指针>
      如果 (流量统计类.获取网卡接口信息 (MIB) == 0)
      {
         MIB.枚举循环 ()
         {
            调试输出 (MIB.取枚举值 ().InterfaceIndex, MIB.取枚举值 ().Description.取文本 (), MIB.取枚举值 ().InOctets, MIB.取枚举值 ().OutOctets)
         }
         MIB.销毁 ()

      }

}
}

作者: kanshijian 时间: 3 天前

Xelloss0618 发表于 2025-9-15 10:02
类流量统计类
{
方法获取网卡接口信息

X大佬,有没有非嵌入式的,嵌入式实在学不会,我发的那种应该怎么改

作者: Xelloss0618 时间: 3 天前

kanshijian 发表于 2025-9-15 10:20
X大佬,有没有非嵌入式的,嵌入式实在学不会,我发的那种应该怎么改

没法改，这个还是嵌入式方法最简单。
MIB_IF_ROW2这个结构体太复杂了，你要用结构类必须把它的全部成员都封装出来，而且每个类型的尺寸不能错。

作者: kanshijian 时间: 3 天前

Xelloss0618 发表于 2025-9-15 10:33
没法改，这个还是嵌入式方法最简单。
MIB_IF_ROW2这个结构体太复杂了，你要用结构类必须把它的全部成员都 ...

谢谢提供的思路

欢迎光临递归火山软件开发平台 (https://bbs.voldp.com/)